電子工作７６ – LM61温度センサでプラスとマイナス温度を液晶に表示する
概要
今回は前回の電子工作７５の続きとしてマイナス温度、例えば、冷蔵庫の冷凍室の温度を測定する方法を検討した。LM61というセンサは精度はあまりよくないが、安価でー３０℃から＋１００℃位まで測れるので使ってみることにした。難しかったところはプログラムの作成で、とにかく、いろんな実験をしてプログラムを改造し、やっとほぼ納得できる温度表示が出来るようになった。
製作にあたって考えていたこと：
１） マイナス温度の測定、表示法の基本を学ぶ。
２） 簡易化のため出来るだけ前回の電子工作７５の回路を利用する。
３） PICマイコンは前回と同じ１６F８１９を使う。
材料：
温度センサLM61BIS： 測定範囲 ー３０℃ to ＋１００℃、 精度max +/-３ to ４℃、温度上昇率 10mV/℃、オフセット電圧 +600mV。温度T（℃）とセンサ出力Vo（mV）の間に下表のような関係がある。式で表すと； Vo（mV）＝１０xT（℃）＋６００、従ってセンサ出力Voが分かればその時の温度Tが計算できる。
|
温度（T） |
出力（Vo） |
|
+100℃ |
+1600mV |
|
+85℃ |
+1450mV |
|
+25℃ |
+850mV |
|
0℃ |
+600mV |
|
-25℃ |
+350mV |
|
-30℃ |
+300mV |
回路図
下に回路図を示す。 前の電子工作７５のものとほぼ同じである。今回は温度センサLM61BISを１個を使用。基準電圧も分圧回路からつくった２．５０Vを用いている。温度センサへの電源も１６F８１９用の電源と同じVdd＝５．０Vを用いている。温度センサLD61BISは-３０℃から＋１００℃までと測定でき測定範囲は広いが、精度はあまり高くない。とにかくマイナス温度を測るのが主目的である。
実験中: 冷蔵庫の冷凍室の温度を測定しているところ。上に市販の温度計（数年以上前に秋葉原の秋月で購入、精度+/-０．５℃）と下の液晶上の温度とは２℃ほどの差が見られる。両者の精度から考えて実際の温度は大体この辺にあると思われる。室内にしばらく置いてあった温度計センサ部を冷凍室に入れると、室温から次第に温度が下がり０℃をスムーズに超えてマイナス温度を示しながら下がって行く。センサ部を半田ごてに当てて電源SWを入れると表示温度は次第に上がり、少なくとも１０５℃までは達することを確認した（破壊を恐れてこの温度で中止）。
(Photo 1)
結果＆コメント
１）
マイナス温度を表示させることに成功した。＋１００℃前後（半田ごて）から-２０℃（冷蔵庫の冷凍室）位までスムースに表示できた。
２） センサLM61BIS（４本で￥２００）の精度はあまり良くないので市販の温度計と２℃程度の差が出ることが頻繁に観察された。
３） センサLM61BISは＋６００mVのオフセットを持たすことによって単一プラス電源でマイナス温度の測定を可能にしてある。
４） 基準電圧を下げると精度が上がる。ただし、計算式の係数をその都度変える必要がある。温度センサ出力の単位はmV、 それをPIC内蔵のADCで変換された値の単位はcount、それをしっかり頭に入れておく必要あり。
５） ２０１４．１１．９ 一部修正； 半田ごてでセンサを加熱して行くと６８−７０℃位から一気に９４℃位にジャンプして上昇することが判明。一方、センサ出力は１．２０Vあたりから１．５０Vなどと連続的に上昇する。何が原因かと考え、思いついたのが Vin＝（Vin＊１２２）/５０＋６００ の（Vin＊１２２）の中の計算値がPicbasic Proで扱える最大値６５５３５を超えたためではないかということ。例えば、Vin＊１２２＝６５５３５ Vin=６５５３５/１２２＝５３７、つまりADCの変換値５３７に相当するセンサ出力Vxは Vx/（２５００/１０２３）＝５３７ Vx＝５３７x（２５００/１０２３）＝１３２１mV １３２１−６００＝７２１mV 721/１０（mV/℃）＝７２℃． つまり、計算上は７２℃以上でPicbasic Proで扱えない最大値６５５３５を超えることになる。従って、観察された上記の温度上昇がジャンプする現象はこの最大値を超えたために起こったと思われる。そこで、Vin＝（Vin＊１２２）/５０＋６００ を Vin＝（Vin＊６１）/２５＋６００ に代えた。 つまり、カッコ内の値が最大値を超えないように、122/５０を同じ数値になる61/２５に変えた。その結果、この温度上昇がジャンプする現象は消え、スムースに１００℃付近まで上昇することが分かった。問題解決！
プログラム
今回は温度センサにLM61BISというプラスとマイナス温度を測定できるものを使う。センサからの出力Voと温度Tとの間にはVo（mV）＝１０xT（℃）＋６００ という関係がある。従ってセンサ出力Voが分かれば、温度Tがプログラムの中で計算できる。上に示した表にセンサがカバーする６つの温度に対応する出力が表示してある。プログラうの中でプラス域の温度はVin=(Vin*122)/50-600
Vin=(Vin*６１)/２５-600で計算し、得られた値を Lcdout "Temp=",Dec1 Vin DIG
2,Dec1 Vin DIG 1,".", DEC1 Vin DIG 0,"C" で抽出し表示する。すると２０．４Cなどと表示される。一方、マイナス域の温度は Vin=600-(Vin*122)/50 （またはVin=600-(Vin*61)/25）で計算し、これを Lcdout
"Temp=","-", Dec1 Vin DIG 2,Dec1 Vin DIG 1,".",
DEC1 Vin DIG 0,"C"で抽出し表示する。この際マイナス符号”-“が入る。従って-２０．４Cなどと表示される。両者の計算式に出てくる (Vin*６１)/２５や(Vin*122)/50の中のVinは10-bit
ADCから出てくる変換値（単位： count）である。６１/２５＝１２２/５０＝２４４/１００＝２．４４(mV/count)で、ほんとうはVinに２．４４を直接掛けたいところだがPicbasic
Proでは小数点や、(Vin*122)内が６５５３５以上の数値を扱えないので便宜的にこうなった。例えば、０℃ではVin＝246 countsになり２４６x２．４４(＝２４６x（122/５０）)＝６００mV、したがってVin=600-(Vin*122)/50 Vin＝６００―６００＝０ （mV）。こうして抽出表示結果は０℃となる。 -２０℃の場合だと、-２０℃x１０mV/℃＋６００mV＝４００mV、４00mV/（２５００mV/１０２３）＝１６３
counts、つまりVin＝１６３ counts、Vin=６００―（１６３x１２２）/５０＝６００―３９８＝２０２、この値２０２の三桁をすべた抽出し、マイナス符号と小数点を付けて –２０．２Cと液晶に表示する。またプログラムの中で使われているIf
Vin=<246 thenの中の２４６は0℃（６００mV）に相当するcount値である。つまり、Vin=Samples/10の結果が２４６（センサ出力６００mVや０℃に相当）に等しいか、小さいかによってプラス温度域かマイナス温度域かを判別して別々のルーチンで処理をさせプラスまたはマイナスの温度表示をさせる。
'****************************************************************
'Name of program: LCDtempLm61BIZ16F819A.bas - 2014.11.4 New 11.6 worked OK 11.7
'Using Picbasic Pro V2.50A and 16F819
'All pin connections to LCD display and 16F819 are the same as those shown in LCDtempLm61BIZ16F819.bas
'As Vref+, used is 2.50V which is made by a voltage divider using two 10K Rs and connected to AN3 (RA3)
'**New LCD connection setting** See p.88 in PBP Manual
DEFINE LCD_DREG PORTB 'Set LCD Data port
DEFINE LCD_DBIT 4 'Set starting Data bit, (0 or 4) if 4-bit bus
DEFINE LCD_RSREG PORTB 'Set LCD Register Select port
DEFINE LCD_RSBIT 1 'Set LCD Register Select bit
DEFINE LCD_EREG PORTB 'Set LCD Enable port
DEFINE LCD_EBIT 0 'Set LCD Enable bit
DEFINE LCD_BITS 4 'Set LCD bus size (4 or 8 bits)
DEFINE LCD_LINES 2 'Set number of lines on LCD
DEFINE LCD_COMMANDUS 2000 'Set command delay time in us
DEFINE LCD_DATAUS 50 'Set data delay time in us
'**Setting for ADC of 16F819**
Define ADC_BITS 10 '10-bit ADC used
Define ADC_CLOCK 3 'Internal clock used
Define ADC_SAMPLEUS 50 'Sample timing
OSCCON=%01110100 'Internal OSC setting to 8MHz
ADCON1=%10000001 'Right adjusted, AN3 - Vref+
TRISA=%00101111 'RA3 - Vref+, PortA.0, 1, 2, 3 and 5 - analog input
TRISB=%00000000 'All PortBs are output
Samples var word 'Samples
Sample var byte 'Sample
Vin var Word 'Vin is variable
Ch var byte 'Ch is channel
Temp2loop:
'---Temp at Point A routine---
Vin=0
Sample=0
Samples=0
ADCON0=%10000101 'for ADC setting of Sensor A (AN0)
Ch=0
For Sample=1 to 10 'Take 10 samples
ADCIN Ch, Vin 'Read ADC ch-0 and save in Vin, Range 0-1023
Samples=Samples + Vin
Pause 200 'Wait for LCD to startup, Seems to be appropriate.
Next sample
Vin=Samples/10 'Mean of 10 Vin values, described in count value
If Vin=<246 then '0C - +600mV 600mV/(2500mV/1023)=246 counts
Goto NegativeTemp
Endif
Vin=(Vin*６１)/２５-600 'Key positive-temperatures calculation formula, ６１/２５＝122/50=244/100=2.44(mV/count) modified on 2014.11.9
Lcdout $fe, 1 'Clear LCD
Lcdout $fe, 2, "Point A"
LCDOUT $FE,$C0 'Jump to second line
Lcdout "Temp=",Dec1 Vin DIG 2,Dec1 Vin DIG 1,".", DEC1 Vin DIG 0,"C"
Pause 3000
Goto Temp2loop
NegativeTemp: ‘negative-temperature: displaying routine
Vin=600-(Vin*122)/50 ‘Key negative-temperature calculation formula Vin=600-(Vin*61)/25 is OK too.
Lcdout $fe, 1 'Clear LCD
Lcdout $fe, 2, "Point A"
LCDOUT $FE,$C0 'Jump to second line
Lcdout "Temp=","-", Dec1 Vin DIG 2,Dec1 Vin DIG 1,".", DEC1 Vin DIG 0,"C"
Pause 3000
Goto Temp2loop
'Note: melabs U2 Programmer's configuration for 16F819 (2014.10.1)
'FOSC-INTRC(INTIO2), WDTE-Enable, PWRTE-Enable, MCLRE-Reset,
'BODEN-Enable, LVP-Disable, CCP Multi With-RB2,
'Flash Pogram Meory Write Enable-All,
'Code-Not Protected, Data EEPROM-Not Protected
'**************************************************